ΔΙΔΑΣΚΑΛΙΑ ΓΡΑΜΜΙΚΩΝ ΣΥΝΑΡΤΗΣΕΩΝ ΣΤΗΝ Γ΄ ΓΥΜΝΑΣΙΟΥ ΜΕ ΤΗ ΒΟΗΘΕΙΑ ΤΟΥ MATHEMATICA
ΚΩΝΣΤΑΝΤΙΝΟΣ ΚΟΡΡΕΣ

ΣΗΜΕΙΩΣΗ: Στο παρόν ηλεκτρονικό φύλλο εργασίας για τις «δυναμικές» αναπαραστάσεις,έχει γίνει χρήση της εντολής:
Do[έκφραση που περιέχει μία παράμετρο,{παράμετρος n,n1,n2,step}],
η οποία ισχύει στις παλαιότερες εκδόσεις του Mathematica (όπως οι εκδόσεις 4 και 5).
Αν χρησιμοποιείτε μία νεότερη έκδοση του Mathematica (όπως η έκδοση 10),τροποποιείστε την παραπάνω εντολή σε
Manipulate[έκφραση που περιέχει μία παράμετρο,{παράμετρος n,n1,n2,step}].

Το θέμα της γραμμικής συνάρτησης y=αx+β,είναι ένα σημαντικό θέμα τόσο για τη μαθηματική εκπαίδευση,όσο και για την εκπαίδευση των υπολοίπων μαθημάτων θετικών επιστημών,με πολλές και ενδιαφέρουσες εφαρμογές. Το θέμα της γραμμικής συνάρτησης y=αx+β εισάγεται με τη μορφή ενός σπειροειδούς προγράμματος,στο Γυμνάσιο και επαναδιδάσκεται στο Λύκειο και έπειτα στα πρώτα έτη του Πανεπιστημίου,μάλιστα περισσότερο αναλυτικά στις Οικονομικές Σχολές.
Η προσέγγιση που ακολουθεί έχει ως στόχο να βοηθήσει τους μαθητευόμενους να κατασκευάσουν τη έννοια της γραμμικής συνάρτησης,μέσω μιας διαδικασίας ανακάλυψης,όπου θεωρούμε μία γραμμική συνάρτηση,δημιουργούμε τον πίνακα τιμών της συνάρτησης,τον απεικονίζουμε σε ένα σύστημα καρτεσιανών συντεταγμένων,ώστε να δημιουργήσουν την εικασία ότι η γραφική παράσταση είναι ευθεία γραμμή.Σε ανώτερα επίπεδα το βήμα αυτό μπορεί να παραληφθεί και να προχωρήσουμε απευθείας στη μελέτη της γραφικής παράστασης μίας γραμμικής συνάρτησης ανάλογα με τη μεταβολή των παραμέτρων της.
	
	Θεωρούμε τη γραμμική συνάρτηση f(x)=2 x,την οποία ορίζουμε στο Mathematica ως εξής:

f[x_] := 2*x

Δημιουργούμε τον πίνακα τιμών της συνάρτησης:

Table[{x, f[x]}, {x, -4, 4, 1}]

Ο πίνακας τιμών μπορεί να πάρει την «παραδοσιακή» μορφή που χρησιμοποιούμε στα Μαθηματικά με τη χρήση της εντολής TableForm:

\(TraditionalForm\`TableForm[
Table[{x, 
          f[x]}, {x, \(-4\), 4, 1}], 
      TableHeadings -> {None, 
{"x", "f(x)"}}, \ TableAlignments -> Right, TableDirections -> Row]\)

Η γραφική παράσταση του πίνακα τιμών σ’ ένα καρτεσιανό σύστημα συντεταγμένων γίνεται με τη χρήση της εντολής ListPlot:

ListPlot[
      Table[{x, f[x]}, {x, -4, 4, 
          1}], 
AspectRatio -> Automatic, 
      Ticks -> {Range[-4, 4, 1], Range[-8, 8, 2]}, 
      PlotStyle -> {AbsolutePointSize[5], RGBColor[1, 0, 0]}]

Μπορούμε να «πυκνώσουμε» σταδιακά τα σημεία στην γραφική παράσταση μειώνοντας το βήμα στη σύνταξη της Table. Στη συνέχεια με τη χρήση της επιλογής PlotJoined -> True ενώνουμε τα σημεία ώστε να προκύψει μία συνεχής γραμμή. Μπορούμε επίσης να παραστήσουμε γραφικά τα σημεία και ταυτόχρονα τη γραφική παράσταση της συνάρτησης στο ίδιο σύστημα αξόνων:

p = 
      ListPlot[Table[{x, f[x]}, {x, -4, 4, 
            0.5}], 
AspectRatio -> Automatic, 
        Ticks -> {Range[-4, 4, 1], Range[-8, 8, 2]}, 
        PlotStyle -> {AbsolutePointSize[5], RGBColor[1, 0, 0]}]

q = 
      ListPlot[Table[{x, 2*x}, {x, -4, 4, 
            0.5}], 
AspectRatio -> Automatic, 
        Ticks -> {Range[-4, 4, 1], Range[-8, 8, 2]}, 
        PlotJoined -> True, 
        PlotStyle -> {Thickness[0.03], RGBColor[0, 1, 0]}]

Show[q, p]

Με αντίστοιχο τρόπο  μπορούμε να κατασκευάσουμε ένα πίνακα τιμών για διάφορες τιμές του συντελεστή διεύθυνσης:

\(TraditionalForm\`TableForm[
      Table[{x, \(-x\), 0.5*x, \(-0.5\)*x, 4*x, \(-4\)*x}, {x, \(-4\), 4, 
          1}], TableHeadings -> {None, {"x", "-x", "0,5 x", "-0,5 x", "4 x", "-4 x"}}, TableDirections -> Row, 
      TableAlignments -> Right]\)

Μπορούμε να μελετήσουμε τη μεταβολή του γραφήματος μιας συνάρτησης ανάλογα με τη μεταβολή των παραμέτρων με τη βοήθεια του προγράμματος. Ειδικότερα μπορούμε να σχεδιάσουμε πολλές γραφικές παραστάσεις συναρτήσεων στο ίδιο γράφημα χρησιμοποιώντας διαφορετικά χρώματα ή αποχρώσεις του γκρί. Για παράδειγμα μπορούμε να σχεδιάσουμε τις γραμμικές συναρτήσεις f(x) = α x, για α=-4(2)4, όπως ακολουθεί:

Plot[
      Table[a*x, {a, -4, 4, 2}] // Evaluate, {x, -6, 
        6}, 
AspectRatio -> 1, 
      Ticks -> {Range[-6, 6, 2], Automatic}, 
      PlotStyle -> {{Hue[1], Thickness[0.01]}, {Hue[0.3], 
            Thickness[0.01]}, {Hue[0.1], Thickness[0.01]}, {Hue[0.7], 
            Thickness[0.01]}, {Hue[0.8], Thickness[0.01]}}, 
      PlotRange -> {{-5, 6}, {-11, 11}}, 
      Epilog -> 
        Table[Text[
            TableForm[{{"α =", a}}, 
              TableSpacing -> {1}], {5 - 0.5  Abs[a], 
              2.5*a}], {a, -4, 4, 2}]]

Η παραπάνω αναπαράσταση είναι μία «στατική» αναπαράσταση της μεταβολής της γραφικής παράστασης της f(x) = α x, καθώς μεταβάλλεται η παράμετρος α. Μία «δυναμική» αναπαράσταση της μεταβολής αυτής μπορεί να γίνει με τη χρήση της εντολής: 
Do[έκφραση που περιέχει μία παράμετρο, {παράμετρος, a, b, step}].
	
Η παρακάτω εντολή σχηματίζει τη γραφική παράσταση της f(x) = - 2 x + b, για b = - 5 (1) 5 βήμα βήμα. Για να δούμε τα γραφήματα ως «animation», επιλέγουμε τα γραφήματα που έχουν σχεδιαστεί και επιλέγουμε από το μενού επιλογών: Cell  AnimateSelectedGraphics.

Do[
      Plot[{-2*x + b, -2*x} // Evaluate, {x, -4, 
          4}, 
AspectRatio -> 1,  
        Ticks -> {Range[-4, 4, 1], Range[-6, 6, 1]}, 
        PlotStyle -> {{RGBColor[1, 0, 0], 
              Thickness[0.01]}, {RGBColor[0, 1, 0], Thickness[0.01]}}, 
        PlotRange -> {{-5, 4}, {-7, 7}}, 
        Epilog -> {Text[
              TableForm[
                If[b < 0,  {{"y = -2 x -", 
                      Abs[b]}} , {{"y = -2 x + ", b}}], 
                TableSpacing -> {1}], {2, -1 + b}],  
            Text[TableForm[{{"y = -2 x "}}, 
                TableSpacing -> {1}], {-3, 6}]  }], {b, -5, 5, 
        1}]

O συσχετισμός του συντελεστή διεύθυνσης της ευθείας με την εφαπτομένη που σχηματίζει η γραφική παράσταση της ευθείας με τον άξονα x΄x μπορεί να γίνει με τη χρήση ενός animation το οποίο θα παρουσιάζει σημεία στη γραφική παράσταση της ευθείας και ταυτόχρονα τις προβολές στους δύο άξονες. Με κατάλληλες ερωτήσεις οι μαθητές μπορούν να οδηγηθούν να ανακαλύψουν την γεωμετρική αυτή ιδιότητα. Ειδικότερα:

\(TraditionalForm\`Do[
      Plot[2*x, {x, \(-4\), 4}, 
AspectRatio -> 
          Automatic, Ticks -> {Range[\(-4\), 4, 1], Range[\(-8\), 8, 2]}, 
        PlotStyle -> {Thickness[0.015], RGBColor[0, 0, 1]}, 
        PlotRange -> {{\(-6\), 6}, {\(-9\), 9}}, 
        PlotLabel -> 
          TableForm[{{\*""εφω = Δ(y/Δ)x = "", \ \((f[t] - f[0])\)/\((t - 
                      0)\)}, {"Δy = ", 
                f[t] - f[0]}, {"Δx = ", \ t - 0}}, 
            TableSpacing -> {0, 0}, TableAlignments -> Center], \ 
        Epilog -> {{Hue[1], Thickness[0.015], 
              Line[{{t, 2*t}, {0, 2*t}}]}, 
{Hue[0.3], 
              Thickness[0.015], 
              Line[{{t, 2*t}, {t, 0}}]}, 
Disk[{t, 2*t}, 
              0.2]}], {t, \(-4\), 4, 1}]\)

Μπορούμε να μελετήσουμε τις γραμμικές συναρτήσεις, δημιουργώντας υποπρογράμματα στο Mathematica, μέσω των οποίων δημιουργούμε τον πίνακα τιμών συνάρτησης, απεικονίζουμε τα σημεία του πίνακα τιμών σε ένα σύστημα αξόνων και δημιουργούμε μια αναπαράσταση του συντελεστή διεύθυνσης ευθείας, ώστε να τον συσχετίσουμε με την εφαπτομένη που σχηματίζει η γραφική παράσταση της ευθείας με τον άξονα x΄x .  
Ειδικότερα έχουμε τα υποπρογράμματα pinakastimon[f,{a,b,step}],sxediasepinaka[f,{a,b,step},{color,enosi}] και 
Syntelestis[f,{a,b,step}] αντίστοιχα.

Δημιουργούμε τα υποπρογράμματα:

pinakastimon[f_, {a_, b_, step_}] := 
      TableForm[Table[{x, f[x]}, {x, a, b, step}], 
        TableHeadings -> {None, {"x", "f(x)"}}, 
        TableAlignments -> Right, TableDirections -> Row]

sxediasepinaka[f_, {a_, b_, step_}, {color_, enosi_}] := 
      ListPlot[Table[{x, f[x]}, {x, a, b, step}], 
        PlotStyle -> {If[enosi == True, Thickness[0.015], 
              AbsolutePointSize[4]], color}, 
        PlotJoined -> If[enosi == True, True, False], 
        AspectRatio -> Automatic, 
        Ticks -> {Range[a, b, 1], 
            Range[Min[Table[f[x], {x, a, b}]], Max[Table[f[x], {x, a, b}]], 
              1]}]

Syntelestis[f_, {a_, b_, step_}] := 
      Do[Plot[f[t], {t, a, b}, PlotStyle -> RGBColor[0, 0, 1], 
          Ticks -> {Range[a, b, 1], 
              Range[Min[Table[f[y], {y, a, b}]], Max[Table[f[y], {y, a, b}]], 
                1]}, PlotRange -> {{a - 1, 
                b + 1}, {-1 + Min[Table[f[y], {y, a, b, step}]], 
                1 + Max[Table[f[y], {y, a, b, step}]]}}, 
          AspectRatio -> Automatic, 
          Epilog -> {Disk[{x, f[x]}, 0.15], Hue[1], 
              Line[{{x, f[x]}, {0, f[x]}}], Hue[0.3], 
              Line[{{x, f[x]}, {x, 0}}]}], {x, b, a, -step}]

Θεωρούμε τη γραφική παράσταση της f(x) = 2x, δημιουργούμε τον πίνακα τιμών της και απεικονίζουμε τα σημεία του πίνακα τιμών σε ένα σύστημα αξόνων:

f[x_] := 2*x

pinakastimon[f, {-4, 4, 1}]

p1 = 
      sxediasepinaka[f, {-4, 4, 1}, {Hue[1], False}]

p2 = 
      sxediasepinaka[f, {-4, 4, 1}, {Hue[0.3], True}]

Show[p2, p1]

Επίσης "τρέχουμε" το animation του συσχετισμού του συντελεστή διεύθυνσης με την εφαπτομένη που σχηματίζει η γραφική παράσταση της ευθείας με τον άξονα x΄x:

Syntelestis[f, {-4, 4, 1}]

Κάνουμε την ίδια ακριβώς διαδικασία για τις συναρτήσεις h(x) = -2x και g(x) = -2x + 1:

h[x_] := -2*x

Syntelestis[h, {-4, 4, 1}]

g[x_] := -2*x + 1

pinakastimon[g, {-4, 4, 1}]

q1 = 
      sxediasepinaka[g, {-4, 4, 1}, {Hue[0.7], False}]

q2 = 
      sxediasepinaka[g, {-4, 4, 1}, {Hue[0.3], True}]

Show[q2, q1]

Μπορούμε να ερμηνεύσουμε γεωμετρικά την επίλυση ενός συστήματος 2x2 ως την εύρεση του σημείου τομής δύο γραμμικών συναρτήσεων. Παρουσιάζουμε στη συνέχεια ένα πρόβλημα το οποίο αφορά την ελαχιστοποίηση των εξόδων για ένα ταξίδι από την Αθήνα στην Πάτρα, για το οποίο έχουμε ως εναλλακτικές να πάρουμε ταξί ή λεωφορείο. Με δεδομένες τις "ταρίφες" και τα έξοδα ανά χιλιόμετρο, οι μαθητές μπορούν να κατασκευάσουν με κατάλληλη καθοδήγηση τις συναρτήσεις εξόδων: 
taxi(x) = 0.1 x + 1 και 
ktel(x) = 0.05 x + 6.5. 
	
Οι γραφικές παραστάσεις των συναρτήσεων αυτών με τη βοήθεια του προγράμματος είναι:

taxi[x_] := 0.1*x + 1

ktel[x_] := 0.05*x + 6.5

t1 = 
      Plot[taxi[x] // Evaluate, {x, 0, 
          200}, 
PlotStyle -> {Hue[0.7], 
            Thickness[0.01]}, PlotRange -> {{0, 200}, {0, 20}}, 
        Ticks -> {Range[0, 200, 20], Range[0, 20, 1]}, 
        AxesLabel -> {"km",  "Euros"}]

t2 = 
      Show[Plot[ktel[x] // Evaluate, {x, 0, 80}, 
          PlotStyle -> {Hue[1], Dashing[{0.015}], Thickness[0.01]}, 
          PlotRange -> {{0, 200}, {0, 20}}, 
          Ticks -> {Range[0, 200, 20], Range[0, 20, 1]}], 
        Plot[ktel[x] // Evaluate, {x, 80, 200}, 
          PlotStyle -> {Hue[1], Thickness[0.01]}, 
          PlotRange -> {{0, 200}, {0, 20}}, 
          Ticks -> {Range[0, 200, 20], Range[0, 20, 1]}, 
          AxesLabel -> {"km",  "Euros"}]]

Στους μαθητές μπορούμε να θέσουμε το πρόβλημα σχετικά με το ποιο μέσο μεταφοράς έχει μικρότερα έξοδα και μέχρι ποια απόσταση η χρήση του ταξί έχει μικρότερα έξοδα από τη χρήση του λεωφορείου, το οποίο οδηγεί στην επίλυση του 2x2 συστήματος των δύο συναρτήσεων. Ο δάσκαλος μπορεί να καθοδηγήσει τους μαθητές να αποφασίσουν σχετικά με το ποιο μέσο μεταφοράς έχει μικρότερα έξοδα για διάφορες πόλεις μεταξύ Αθήνας - Πάτρας παρατηρώντας το γράφημα των δύο συναρτήσεων.

Show[t1, t2, 
      GridLines -> {{20, 40, 60, 80, 100, 120, 140, 160, 180, 200}, {4, 
            8, 12, 16, 20}},  
      Epilog -> {{Text[
              TableForm[{{"y = 0.1 x + 1"}}, 
                TableSpacing -> {1}], {80, 5}], 
            Text[TableForm[{{"y = 0.05 x + 6.5"}}, 
                TableSpacing -> {1}], {100, 15}]}, {AbsolutePointSize[
              8], Point[{110, taxi[110]}]}}, 
      AxesLabel -> {"km",  "Euros"}]

Βιβλιογραφία:
1) Κορρές Κ. (2003). Η χρήση του Η/Υ ως γνωστικού εργαλείου στη διδασκαλία των μαθηματικών. Πρακτικά του 20ου Πανελλήνιου Συνεδρίου Μαθηματικής Παιδείας της Ελληνικής Μαθηματικής Εταιρείας, με τίτλο «Η διαδρομή του παιδιού από την προσχολική ηλικία μέχρι την ενηλικίωση». Βέροια, 7 - 9 Νοεμβρίου 2003.
2) Kyriazis A. & Korres K. (2002). Teaching Linear Functions in Junior High School, with the use of Computers. Proceedings of the 3rd Hellenic Conference with International participation, of the Hellenic Scientific Association of Information & Communication Technologies in Education (ETPE). 
3) Κυριαζής Α. & Κορρές Κ. (2001). Θέματα Δευτεροβάθμιας Εκπαίδευσης: Μελέτη θεμάτων με τη βοήθεια του Mathematica®. Σημειώσεις επιμόρφωσης στα πλαίσια του επιμορφωτικού προγράμματος ετήσιας διάρκειας, για τους εκπαιδευτικούς Μαθηματικούς», για το μάθημα «Νέες Τεχνολογίες στην Εκπαίδευση», με διδάσκοντα τον κ. Α. Κυριαζή, Καθηγητή. Τμήμα Μαθηματικών, Πανεπιστήμιο Αθηνών.